{
  pkgs,
  lib,
  config,
  ...
}:
{
  imports = [
    # Include the results of the hardware scan.
    ./hardware.nix
    ./home.nix
    ./ssh.nix
    ./web
    ./sops.nix
  ];

  boot.loader.grub.device = "/dev/sda";
  time.timeZone = "Europe/Helsinki";

  environment.systemPackages = [ pkgs.cifs-utils ];
  fileSystems."/mnt/storage-box" = {
    device = "//u423859-sub3.your-storagebox.de/u423859-sub3";
    fsType = "cifs";
    options =
      let
        opts = lib.concatStringsSep "," [
          "x-systemd.automount"
          "noauto"
          "x-systemd.idle-timeout=60"
          "x-systemd.device-timeout=5s"
          "x-systemd.mount-timeout=5s"
          "credentials=${config.sops.secrets.samba-creds.path}"
          "gid=${toString config.users.groups.storage-box.gid}"
        ];
      in
      # No clue whether doing it like this is neccessary, but the wiki does it
      # like this
      [ opts ];
  };

  networking = {
    hostName = "sagittarius";
    useNetworkd = true;
    firewall.allowedTCPPorts = [ 22 ];
  };
  systemd.network = {
    enable = true;
    networks."10-wan" = {
      matchConfig.Name = "enp1s0";
      networkConfig.DHCP = "ipv4";
      address = [ "2a01:4f9:c012:c7a7::/64" ];
      routes = [ { Gateway = "fe80::1"; } ];
    };
  };

  # Set the max amout of space used for logs
  services.journald.extraConfig = ''
    SystemMaxUse=100M
  '';

  services.comin = {
    enable = true;
    remotes = [
      {
        name = "origin";
        url = "https://git.sorre.xyz/miranb/nixos-config.git";
        branches.main.name = "main";
        auth.access_token_path = config.sops.secrets."sorre-forgejo-access-token".path;
      }
    ];
  };

  # Select internationalisation properties.
  i18n.defaultLocale = "en_US.UTF-8";

  programs.gnupg.agent = {
    enable = true;
    enableSSHSupport = true;
  };

  users = {
    groups.storage-box = { };
    users = {
      ascella = {
        isNormalUser = true;
        extraGroups = [ "wheel" ];
        openssh.authorizedKeys.keys = [
          "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIKiDCf9LMx9diW5BveEju9w2Xv2kk7qKCyLESLyymzih ihp@ihp-laptop"
          "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIM4aG8NI25TgjcDevjsY/Y6d3iYsQxSEtIpsqprMHmad osiris@underworld"
        ];
      };
    };
  };

  # This value determines the NixOS release from which the default
  # settings for stateful data, like file locations and database versions
  # on your system were taken. It‘s perfectly fine and recommended to leave
  # this value at the release version of the first install of this system.
  # Before changing this value read the documentation for this option
  # (e.g. man configuration.nix or on https://nixos.org/nixos/options.html).
  system.stateVersion = "23.05"; # Did you read the comment?
}