blob: 72f753ef9cb693886b85558288f98314c2885a85 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
{
description = "My NixOs dotfiles";
inputs = {
nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
flake-utils.url = "github:numtide/flake-utils";
disko = {
url = "github:nix-community/disko";
inputs.nixpkgs.follows = "nixpkgs";
};
home-manager = {
url = "github:nix-community/home-manager";
inputs.nixpkgs.follows = "nixpkgs";
};
sops-nix = {
url = "github:Mic92/sops-nix";
inputs.nixpkgs.follows = "nixpkgs";
};
sorre-website = {
url = "git+https://codeberg.org/miranb/sorre-website.git";
inputs.nixpkgs.follows = "nixpkgs";
};
snippets-ls = {
url = "github:quantonganh/snippets-ls";
inputs.nixpkgs.follows = "nixpkgs";
};
};
outputs = { flake-utils, ... }@inputs:
flake-utils.lib.eachDefaultSystem (system:
let pkgs = inputs.nixpkgs.legacyPackages.${system};
in {
formatter = pkgs.nixfmt;
devShells.default =
pkgs.mkShell { buildInputs = with pkgs; [ git gitui sops ]; };
}) // {
nixosConfigurations = let
generateNixosConfig = name: _value: {
system =
"x86_64-linux"; # I don't have any other type of machine yet
modules = with inputs; [
home-manager.nixosModules.home-manager
sops-nix.nixosModules.sops
disko.nixosModules.disko
./share/system/common.nix
# This directory has to exist and have a `default.nix` in it, see
# `./hosts` directory for examples
./hosts/${name}
];
specialArgs = {
inherit inputs;
flakeRoot = ./.;
};
};
# wrapper around nixpkgs.lib.nixosSystem to enable using it on attrsets
generateNixosSystem = _name: value:
inputs.nixpkgs.lib.nixosSystem value;
hosts = builtins.readDir ./hosts;
nixosConfigs = builtins.mapAttrs generateNixosConfig hosts;
# If you want to add something to a particular system, do it here before
# the `in ...` line
in builtins.mapAttrs generateNixosSystem nixosConfigs;
};
}
|
