blob: e309883822daac0802b370f6c51d23528d71517b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
|
{
description = "My NixOs dotfiles";
inputs = {
nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
disko = {
url = "github:nix-community/disko";
inputs.nixpkgs.follows = "nixpkgs";
};
home-manager = {
url = "github:nix-community/home-manager";
inputs.nixpkgs.follows = "nixpkgs";
};
flake-parts.url = "github:hercules-ci/flake-parts";
devshell = {
url = "github:numtide/devshell";
inputs.nixpkgs.follows = "nixpkgs";
};
sops-nix = {
url = "github:Mic92/sops-nix";
inputs.nixpkgs.follows = "nixpkgs";
};
treefmt-nix = {
url = "github:numtide/treefmt-nix";
inputs.nixpkgs.follows = "nixpkgs";
};
pre-commit-hooks-nix = {
url = "github:cachix/pre-commit-hooks.nix";
inputs.nixpkgs.follows = "nixpkgs";
};
sorre-website = {
url = "git+https://codeberg.org/miranb/sorre-website.git";
inputs.nixpkgs.follows = "nixpkgs";
inputs.flake-parts.follows = "flake-parts";
inputs.devshell.follows = "devshell";
inputs.treefmt-nix.follows = "treefmt-nix";
};
snippets-ls = {
url = "github:quantonganh/snippets-ls";
inputs.nixpkgs.follows = "nixpkgs";
};
};
outputs =
inputs@{ flake-parts, ... }:
inputs.flake-parts.lib.mkFlake { inherit inputs; } {
systems = [ "x86_64-linux" ];
imports = [
inputs.devshell.flakeModule
inputs.treefmt-nix.flakeModule
inputs.pre-commit-hooks-nix.flakeModule
];
flake.nixosConfigurations =
let
generateNixosConfig = name: _value: {
system = "x86_64-linux"; # I don't have any other type of machine yet
modules = [
inputs.home-manager.nixosModules.home-manager
inputs.sops-nix.nixosModules.sops
inputs.disko.nixosModules.disko
./share/system/common.nix
# This directory has to exist and have a `default.nix` in it, see
# `./hosts` directory for examples
./hosts/${name}
];
specialArgs = {
inherit inputs;
flakeRoot = ./.;
};
};
# wrapper around nixpkgs.lib.nixosSystem to enable using it on attrsets
generateNixosSystem = _name: value: inputs.nixpkgs.lib.nixosSystem value;
hosts = builtins.readDir ./hosts;
nixosConfigs = builtins.mapAttrs generateNixosConfig hosts;
# If you want to add something to a particular system, do it here before
# the `in ...` line
in
builtins.mapAttrs generateNixosSystem nixosConfigs;
perSystem =
{ pkgs, config, ... }:
{
devshells.default = {
name = "nixconf-sh";
devshell.startup.pre-commit-install.text = config.pre-commit.installationScript;
packages = (builtins.attrValues config.treefmt.build.programs);
commands = with pkgs; [
{ package = git; }
{ package = gitui; }
{ package = sops; }
{ package = config.treefmt.build.wrapper; }
];
};
treefmt = {
projectRootFile = ./flake.nix;
programs = {
nixpkgs-fmt.enable = true;
};
};
pre-commit = {
check.enable = false;
settings = {
hooks = {
treefmt.enable = true;
treefmt.package = config.treefmt.build.wrapper;
deadnix.enable = true;
};
};
}; # end of pre-commit
}; # end of perSystem
}; # end of inputs.flake-parts.lib.mkFlake
}
|
