hosts/nyaan/wireguard.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

{ config, ... }:
let
  # NOTE: port is the same on every host
  port = 51820;
in
{
  sops = {
    age.keyFile = "/var/lib/sops-nix/key.txt";
    secrets = {
      "wg-priv-key" = {
        sopsFile = ../../secrets/wg-nyaan-private.txt;
        owner = "systemd-networkd";
        group = "systemd-networkd";
        mode = "0640";
        format = "binary";
      };
    };
  };

  networking.firewall.allowedUDPPorts = [ port ];
  networking.useNetworkd = true;

  systemd.network = {
    enable = true;
    networks."50-wg" = {
      matchConfig.Name = "wg0";
      address = [
        "2301:db8:acad:a::2/128"
        "192.168.5.2/32"
      ];
    };
    netdevs."50-wg" = {
      netdevConfig = {
        Kind = "wireguard";
        Name = "wg0";
      };

      wireguardConfig = {
        ListenPort = port;
        PrivateKeyFile = config.sops.secrets."wg-priv-key".path;
        # To automatically create routes for everything in AllowedIPs,
        # add RouteTable=main
        RouteTable = "main";
        # FirewallMark marks all packets send and received by wg0 with the
        # number 42, which can be used to define policy rules on these packets.
        FirewallMark = 42;
      };

      wireguardPeers = [
        {
          # sagittarius
          PublicKey = "u5nh+YNV84IbS7g0ncfs/V+cqEudNh500LQ7pmdS7j0=";
          AllowedIPs = [
            "2301:db8:acad:a::1/128"
            "192.168.5.1/32"
          ];
          Endpoint = "95.216.136.85:${port}";
        }
      ];
    };
  };
}