flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100

{
  description = "My website hosting random thoughts";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-parts.url = "github:hercules-ci/flake-parts";
    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    pre-commit-hooks-nix = {
      url = "github:cachix/pre-commit-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{ flake-parts, ... }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      imports = [
        inputs.treefmt-nix.flakeModule
        inputs.pre-commit-hooks-nix.flakeModule
      ];
      systems = [ "x86_64-linux" ];
      perSystem =
        { config, pkgs, ... }:
        let
          deps = [
            pkgs.soupault
            pkgs.pandoc
            pkgs.highlight
          ];
        in
        {
          packages = {
            default = config.packages.website;

            website = pkgs.stdenv.mkDerivation {
              pname = "sorre-website";
              version = "2026-02-21-patch-1";
              src = ./.;
              nativeBuildInputs = deps;
              buildPhase = "soupault";
              installPhase = "cp -r build $out";
            };

            docker-image = pkgs.dockerTools.buildImage {
              name = "sorre-website";
              tag = "latest";
              config = {
                ExposedPorts = {
                  "8080/tcp" = { };
                };
                Cmd = [
                  "${pkgs.pkgsStatic.darkhttpd}/bin/darkhttpd"
                  "${config.packages.website}"
                  "--port"
                  "8080"
                  "--addr"
                  "0.0.0.0"
                ];
              };
            };
          };

          devShells.default =
            let
              stdenvMinimal = pkgs.stdenvNoCC.override {
                cc = null;
                preHook = "";
                allowedRequisites = null;
                initialPath = pkgs.lib.filter (
                  a: pkgs.lib.hasPrefix "coreutils" a.name
                ) pkgs.stdenvNoCC.initialPath;
                extraNativeBuildInputs = [ ];
              };
              minimalMkShell = pkgs.mkShell.override { stdenv = stdenvMinimal; };
            in
            minimalMkShell {
              packages = deps ++ builtins.attrValues config.treefmt.build.programs;
            };

          treefmt = {
            projectRootFile = "flake.nix";
            programs = {
              nixfmt.enable = true;
            };
          };

          pre-commit = {
            check.enable = true;
            settings.hooks = {
              treefmt.package = config.treefmt.build.wrapper;
              treefmt.enable = true;
              deadnix.enable = true;
            };
          };
        };
    };
}